The & prefix also disables prototype checking, but you shouldn't be using prototypes in the first place, so I consider that a very minor point, but if I didn't mention it, someone else would surely raise that flag. {grin}

In our Learning Perl book, we suggest that you always use the ampersand when you're first learning Perl, because otherwise you'll be a bit befuddled when the following code doesn't work:

sub log {
  print STDERR "logging: ", @_, "\n";
}

...
log("starting");
...
log("finishing");
...

foo("\@_ has elements!");    # prints "Surprise! @_ has elements!"
bar("\@_ has no elements!"); # prints "Surprise!"

sub foo {
    # absent parens say pass my @_
    &baz;
}

sub bar {
    # parens say only pass these arguments (nothing)
    &baz();
}

sub baz {
    print "Surprise! ",join("\t",@_),"\n";
}

Is there ever a scenario when it's preferrable to use the &

There is one dramatic difference that occurs when you call the function without a parameter list:

#! /usr/local/bin/perl -w

use strict;

sub inner {
    print "  inner: $_\n" for @_;
}

sub outer {
    print "outer: $_\n" for @_;
        inner;
        print "\n";
}

sub outer_amp {
    print "outer_amp: $_\n" for @_;
        &inner;
        print "\n";
}

outer( qw/ vroon gukguk faba / );

outer_amp( qw/ foomp tweedle zachitty / );

__RESULTS__

outer: vroon
outer: gukguk
outer: faba

outer_amp: foomp
outer_amp: tweedle
outer_amp: zachitty
  inner: foomp
  inner: tweedle
  inner: zachitty

When using the &inner; variant, whatever remains of @_ in the calling routine is passed to the called routine. The only time it's really useful is when doing out-of-the-ordinary stuff like autoloading. In general you should avoid it. It leads to bad surprises

PS: metasyntactic function call arguments courtesy of BooK's Acme::MetaSyntactic module, the donmartin theme.

(tye)Re: A question of style

Where can I learn more about this?

A somewhat related inquiry follows at: Subroutine Bewilderment with some helpful comments.